function AvrLat_y( y_Data )
    !
    ! 1 次元緯度格子点データの緯度方向平均(1 層用). 
    !
    ! 実際には格子点データ各点毎に y_Lat_Weight を掛けた
    ! 総和を計算し, y_Lat_Weight の総和で割ることで
    ! 平均している. 
    !
    ! Meridonal mean of 1-dimensional (latitude)
    ! grid data.
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "y_Lat_Weight" 
    ! and deviding by the sum total of "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: y_Data (1:jmax)
    real(DP):: AvrLat_y

    ! 作業変数
    ! Work variables
    !

    ! 実行文 ; Executable statement
    !
    AvrLat_y = IntLat_y( y_Data ) / sum( y_Lat_Weight )
  end function AvrLat_y

  function AvrLonLat_xy( xy_Data )
    !
    ! 2 次元緯度経度格子点データの全領域平均(1 層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight, y_Lat_Weight を掛けた
    ! 総和を計算し, x_Lon_Weight * y_Lat_Weight の総和で割ることで
    ! 平均している. 
    !
    ! Global mean of 2-dimensional (latitude and longitude)
    ! grid data.
    !
    ! Practically, the mean grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight" and "y_Lat_Weight"
    ! and deviding by the sum total of "x_Lon_Weight" * "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: xy_Data (0:imax-1, 1:jmax)
    real(DP):: AvrLonLat_xy

    ! 実行文 ; Executable statement
    !
    AvrLonLat_xy = AvrLon_x( x_AvrLat_xy( xy_Data ) )
  end function AvrLonLat_xy

  function AvrLon_x( x_Data )
    !
    ! 1 次元経度格子点データの経度方向平均(1 層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight を掛けた
    ! 総和を計算し, x_Lon_Weight の総和で割ることで
    ! 平均している. 
    !
    ! Zonal mean of 1-dimensional (longitude)
    ! grid data.
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight" 
    ! and deviding by the sum total of "x_Lon_Weight".
    !
    implicit none
    real(DP), intent(in):: x_Data (0:imax-1)
    real(DP):: AvrLon_x

    ! 作業変数
    ! Work variables
    !

    ! 実行文 ; Executable statement
    !
    AvrLon_x = IntLon_x( x_Data ) / sum( x_Lon_Weight )
  end function AvrLon_x

  function IntLat_y( y_Data )
    !
    ! 1 次元緯度格子点データの緯度方向積分(1 層用). 
    !
    ! 実際には格子点データ各点毎に y_Lat_Weight を掛けた
    ! 総和を計算している. 
    !
    ! Meridonal integration of 1-dimensional (latitude)
    ! grid data.
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: y_Data (1:jmax)
    real(DP):: IntLat_y

    ! 作業変数
    ! Work variables
    !

    ! 実行文 ; Executable statement
    !
    IntLat_y = sum( y_Data * y_Lat_Weight )
  end function IntLat_y

  function IntLonLat_xy( xy_Data )
    !
    ! 2 次元緯度経度格子点データの全領域積分(1 層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight, y_Lat_Weight を掛けた
    ! 総和を計算している. 
    !
    ! Global integration of 2-dimensional (latitude and longitude)
    ! grid data.
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight" and "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: xy_Data (0:imax-1, 1:jmax)
    real(DP):: IntLonLat_xy

    ! 実行文 ; Executable statement
    !
    IntLonLat_xy = IntLon_x( x_IntLat_xy( xy_Data ) )
  end function IntLonLat_xy

  function IntLon_x( x_Data )
    !
    ! 1 次元経度格子点データの経度方向積分(1 層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight を掛けた
    ! 総和を計算している. 
    !
    ! Zonal integration of 1-dimensional (longitude)
    ! grid data.
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight".
    !
    implicit none
    real(DP), intent(in):: x_Data (0:imax-1)
    real(DP):: IntLon_x

    ! 作業変数
    ! Work variables
    !

    ! 実行文 ; Executable statement
    !
    IntLon_x = sum( x_Data * x_Lon_Weight )
  end function IntLon_x

  function x_AvrLat_xy( xy_Data )
    !
    ! 2 次元緯度経度格子点データの緯度方向平均(1 層用). 
    !
    ! 実際には格子点データ各点毎に y_Lat_Weight を掛けた
    ! 総和を計算し, y_Lat_Weight の総和で割ることで
    ! 平均している. 
    !
    ! Meridional mean of 2-dimensional (latitude and longitude)
    ! grid data.
    !
    ! Practically, the mean grid data is calculated
    ! by multiplying in each grid "y_Lat_Weight" 
    ! and deviding by the sum total of "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: xy_Data (0:imax-1, 1:jmax)
    real(DP):: x_AvrLat_xy (0:imax-1)

    ! 作業変数
    ! Work variables
    !

    ! 実行文 ; Executable statement
    !
    x_AvrLat_xy = x_IntLat_xy ( xy_Data ) / sum( y_Lat_Weight )
  end function x_AvrLat_xy

  function x_IntLat_xy( xy_Data )
    !
    ! 2 次元緯度経度格子点データの緯度方向積分(1 層用). 
    !
    ! 実際には格子点データ各点毎に y_Lat_Weight を掛けた
    ! 総和を計算している. 
    !
    ! Meridional integration of 2-dimensional (latitude and longitude)
    ! grid data.
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: xy_Data (0:imax-1, 1:jmax)
    real(DP):: x_IntLat_xy (0:imax-1)

    ! 作業変数
    ! Work variables
    !
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude

    ! 実行文 ; Executable statement
    !
    x_IntLat_xy = 0.0_DP
    do j = 1, jmax
      x_IntLat_xy = x_IntLat_xy + xy_Data (:,j) * y_Lat_Weight(j)
    enddo
  end function x_IntLat_xy

  function xa_AvrLat_xya( xya_Data )
    !
    ! 3 次元緯度経度格子点データの緯度方向平均(多層用). 
    !
    ! 実際には格子点データ各点毎に y_Lat_Weight を掛けた
    ! 総和を計算し, y_Lat_Weight の総和で割ることで
    ! 平均している. 
    !
    ! Meridional mean of 3-dimensional (latitude and longitude)
    ! grid data. (for multi layer)
    !
    ! Practically, the mean grid data is calculated
    ! by multiplying in each grid "y_Lat_Weight" 
    ! and deviding by the sum total of "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: xya_Data (0:imax-1, 1:jmax, 1:kmax)
    real(DP):: xa_AvrLat_xya (0:imax-1, 1:kmax)

    ! 作業変数
    ! Work variables
    !
    integer:: k               ! 鉛直方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in vertical direction

    ! 実行文 ; Executable statement
    !
    do k = 1, kmax
      xa_AvrLat_xya(:,k) = x_AvrLat_xy( xya_Data(:,:,k) )
    end do
  end function xa_AvrLat_xya

  function xa_IntLat_xya( xya_Data )
    !
    ! 3 次元緯度経度格子点データの緯度方向積分(多層用). 
    !
    ! 実際には格子点データ各点毎に y_Lat_Weight を掛けた
    ! 総和を計算している. 
    !
    ! Meridional integration of 3-dimensional (latitude and longitude)
    ! grid data. (for multi layer)
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "y_Lat_Weight".
    !
    implicit none
    real(DP), intent(in):: xya_Data (0:imax-1, 1:jmax, 1:kmax)
    real(DP):: xa_IntLat_xya (0:imax-1, 1:kmax)

    ! 作業変数
    ! Work variables
    !
    integer:: k               ! 鉛直方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in vertical direction

    ! 実行文 ; Executable statement
    !
    do k = 1, kmax
      xa_IntLat_xya(:,k) = x_IntLat_xy( xya_Data(:,:,k) )
    end do
  end function xa_IntLat_xya

  function y_AvrLon_xy( xy_Data )
    !
    ! 2 次元緯度経度格子点データの経度方向平均(1 層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight を掛けた
    ! 総和を計算し, x_Lon_Weight の総和で割ることで
    ! 平均している. 
    !
    ! Zonal mean of 2-dimensional (latitude and longitude)
    ! grid data.
    !
    ! Practically, the mean grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight" 
    ! and deviding by the sum total of "x_Lon_Weight".
    !
    implicit none
    real(DP), intent(in):: xy_Data (0:imax-1, 1:jmax)
    real(DP):: y_AvrLon_xy (1:jmax)

    ! 作業変数
    ! Work variables
    !

    ! 実行文 ; Executable statement
    !
    y_AvrLon_xy = y_IntLon_xy( xy_Data ) / sum( x_Lon_Weight )
  end function y_AvrLon_xy

  function y_IntLon_xy( xy_Data )
    !
    ! 2 次元緯度経度格子点データの経度方向積分(1 層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight を掛けた
    ! 総和を計算している. 
    !
    ! Zonal integration of 2-dimensional (latitude and longitude)
    ! grid data.
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight".
    !
    implicit none
    real(DP), intent(in):: xy_Data (0:imax-1, 1:jmax)
    real(DP):: y_IntLon_xy (1:jmax)

    ! 作業変数
    ! Work variables
    !
    integer:: i               ! 経度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in longitude

    ! 実行文 ; Executable statement
    !
    y_IntLon_xy = 0.0_DP
    do i = 0, imax - 1
      y_IntLon_xy = y_IntLon_xy + xy_Data (i,:) * x_Lon_Weight(i)
    enddo
  end function y_IntLon_xy

  function ya_AvrLon_xya( xya_Data )
    !
    ! 3 次元緯度経度格子点データの経度方向平均(多層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight を掛けた
    ! 総和を計算し, x_Lon_Weight の総和で割ることで
    ! 平均している. 
    !
    ! Zonal mean of 3-dimensional (latitude and longitude)
    ! grid data. (for multi layer)
    !
    ! Practically, the mean grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight" 
    ! and deviding by the sum total of "x_Lon_Weight".
    !
    implicit none
    real(DP), intent(in):: xya_Data (0:imax-1, 1:jmax, 1:kmax)
    real(DP):: ya_AvrLon_xya (1:jmax, 1:kmax)

    ! 作業変数
    ! Work variables
    !
    integer:: k               ! 鉛直方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in vertical direction

    ! 実行文 ; Executable statement
    !
    do k = 1, kmax
      ya_AvrLon_xya(:,k) = y_AvrLon_xy( xya_Data(:,:,k) )
    end do
  end function ya_AvrLon_xya

  function ya_IntLon_xya( xya_Data )
    !
    ! 3 次元緯度経度格子点データの経度方向積分(多層用). 
    !
    ! 実際には格子点データ各点毎に x_Lon_Weight を掛けた
    ! 総和を計算している. 
    !
    ! Zonal integration of 3-dimensional (latitude and longitude)
    ! grid data. (for multi layer)
    !
    ! Practically, the sum total of grid data is calculated
    ! by multiplying in each grid "x_Lon_Weight".
    !
    implicit none
    real(DP), intent(in):: xya_Data (0:imax-1, 1:jmax, 1:kmax)
    real(DP):: ya_IntLon_xya (1:jmax,1:kmax)

    ! 作業変数
    ! Work variables
    !
    integer:: k               ! 鉛直方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in vertical direction

    ! 実行文 ; Executable statement
    !
    do k = 1, kmax
      ya_IntLon_xya(:,k) = y_IntLon_xy( xya_Data(:,:,k) )
    end do
  end function ya_IntLon_xya

  subroutine InitCheck
    !
    ! 依存モジュールの初期化チェック
    !
    ! Check initialization of dependency modules

    ! モジュール引用 ; USE statements
    !

    ! 格子点設定
    ! Grid points settings
    !
    use gridset, only: gridset_inited

    ! 物理定数設定
    ! Physical constants settings
    !
    use constants, only: constants_inited

    ! 座標データ設定
    ! Axes data settings
    !
    use axesset, only: axesset_inited

    ! 実行文 ; Executable statement
    !

    if ( .not. gridset_inited ) call MessageNotify( 'E', module_name, '"gridset" module is not initialized.' )

    if ( .not. constants_inited ) call MessageNotify( 'E', module_name, '"constants" module is not initialized.' )

    if ( .not. axesset_inited ) call MessageNotify( 'E', module_name, '"axesset" module is not initialized.' )

  end subroutine InitCheck

  subroutine IntAvrOprInit
    !
    ! intavr_operate モジュールの初期化を行います. 
    ! NAMELIST#intavr_operate_nml の読み込みはこの手続きで行われます. 
    !
    ! "intavr_operate" module is initialized. 
    ! "NAMELIST#intavr_operate_nml" is loaded in this procedure. 
    !

    ! モジュール引用 ; USE statements
    !

    ! 宣言文 ; Declaration statements
    !
    implicit none

!!$    integer:: unit_nml        ! NAMELIST ファイルオープン用装置番号. 
!!$                              ! Unit number for NAMELIST file open
!!$    integer:: iostat_nml      ! NAMELIST 読み込み時の IOSTAT. 
!!$                              ! IOSTAT of NAMELIST read

    ! NAMELIST 変数群
    ! NAMELIST group name
    !
!!$    namelist /intavr_operate_nml/
          !
          ! デフォルト値については初期化手続 "intavr_operate#IntAvrOprInit" 
          ! のソースコードを参照のこと. 
          !
          ! Refer to source codes in the initialization procedure
          ! "intavr_operate#IntAvrOprInit" for the default values. 
          !

    ! 実行文 ; Executable statement
    !

    if ( intavr_operate_inited ) return
    call InitCheck

    ! デフォルト値の設定
    ! Default values settings
    !

!!$    ! NAMELIST の読み込み
!!$    ! NAMELIST is input
!!$    !
!!$    if ( trim(namelist_filename) /= '' ) then
!!$      call FileOpen( unit_nml, &          ! (out)
!!$        & namelist_filename, mode = 'r' ) ! (in)
!!$
!!$      rewind( unit_nml )
!!$      read( unit_nml, &           ! (in)
!!$        & nml = intavr_operate_nml, &  ! (out)
!!$        & iostat = iostat_nml )   ! (out)
!!$      close( unit_nml )
!!$
!!$      call NmlutilMsg( iostat_nml, module_name ) ! (in)
!!$    end if

    ! 印字 ; Print
    !
    call MessageNotify( 'M', module_name, '----- Initialization Messages -----' )
    call MessageNotify( 'M', module_name, '-- version = %c', c1 = trim(version) )
    intavr_operate_inited = .true.
  end subroutine IntAvrOprInit