!------------------------------------------------------------------------
! Copyright (c) 2023 SPMODEL Development Group. All rights reserved.
!------------------------------------------------------------------------
!
!表題  et_mpi_module テストプログラム (ヤコビアン計算)
!
!履歴  2023/03/05  竹広真一
!
program et_mpi_module_jacobian_test

  use dc_message, only : MessageNotify
  use dc_test, only : AssertEqual
  use et_mpi_module
  use mpi
  implicit none

  !---- 空間解像度設定 ----
  integer, parameter :: im=64, jm=64            ! 格子点の設定(X,Y)
  integer, parameter :: km=21, lm=42            ! 切断波数の設定(X,Y)
!!$  integer, parameter :: im=32, jm=64              ! 格子点の設定(X,Y)
!!$  integer, parameter :: km=10, lm=42              ! 切断波数の設定(X,Y)

  !---- 変数 ----
  real(8), allocatable :: vx_A(:,:)     ! 格子データ
  real(8), allocatable :: vx_B(:,:)     ! 格子データ
  real(8), allocatable :: vx_Jacob(:,:)  ! 格子データ

  integer, parameter :: k=4,l=2
  integer            :: np, ip, ierr

  !---- 座標変数など ----
  real(8), parameter :: xmin = -1.0d0, xmax=1.0d0
  real(8), parameter :: ymin = -1.0d0, ymax=1.0d0

  real(8), parameter :: pi=3.1415926535897932385D0
  ! 判定誤差設定
  integer, parameter :: check_digits = 10
  integer, parameter :: ignore = -11

  call MessageNotify('M','et_mpi_module_jacobian_test', &
       'et_mpi_module jacobian function tests')

  !---------------- MPI スタート ---------------------
  call MPI_INIT(IERR)
  call MPI_COMM_RANK(MPI_COMM_WORLD,IP,IERR)
  call MPI_COMM_SIZE(MPI_COMM_WORLD,NP,IERR)

  !---------------- 座標値の設定 ---------------------
  call et_mpi_initial(im,jm,km,lm,xmin,xmax,ymin,ymax)    ! スペクトル初期化

  allocate(vx_A(jc(ip),0:im-1))      ! 格子データ
  allocate(vx_B(jc(ip),0:im-1))      ! 格子データ
  allocate(vx_Jacob(jc(ip),0:im-1))  ! 格子データ

  !------------------- 初期値設定 ----------------------
  vx_A = sin(k*pi*vx_X)
  vx_B = sin(l*pi*vx_Y)
  vx_Jacob = k*pi*cos(k*pi*vx_X) * l*pi*cos(l*pi*vx_Y)

  call check2d(vx_ft(ft_Jacobian_ft_ft(ft_vx(vx_A),ft_vx(vx_B))), vx_Jacob, &
    'Jacob(sin(k*pi*X),sin(l*pi*Y))')

  vx_A = cos(k*pi*vx_X)
  vx_B = cos(l*pi*vx_Y)
  vx_Jacob = k*pi*sin(k*pi*vx_X) * l*pi*sin(l*pi*vx_Y)

  call check2d(vx_ft(ft_Jacobian_ft_ft(ft_vx(vx_A),ft_vx(vx_B))), vx_Jacob, &
    'Jacob(cos(k*pi*X),cos(l*pi*Y))')

  vx_A = sin(k*pi*vx_X)
  vx_B = cos(l*pi*vx_Y)
  vx_Jacob = - k*pi*cos(k*pi*vx_X) * l*pi*sin(l*pi*vx_Y)

  call check2d(vx_ft(ft_Jacobian_ft_ft(ft_vx(vx_A),ft_vx(vx_B))), vx_Jacob, &
    'Jacob(sin(k*pi*X),cos(l*pi*Y))')

  vx_A = cos(k*pi*vx_X)
  vx_B = sin(l*pi*vx_Y)
  vx_Jacob = - k*pi*sin(k*pi*vx_X) * l*pi*cos(l*pi*vx_Y)

  call check2d(vx_ft(ft_Jacobian_ft_ft(ft_vx(vx_A),ft_vx(vx_B))), vx_Jacob, &
    'Jacob(cos(k*pi*X),sin(l*pi*Y))')


  call MPI_FINALIZE(IERR)
  
  call MessageNotify('M','et_mpi_module_derivative_test', &
       'et_mpi_module jacobian function tests succefded!')

contains

  subroutine check2d(var,sol,funcname) ! 絶対値が eps 以上の var の要素を出力
    real(8) :: var(:,:)                ! 判定する配列
    real(8) :: sol(:,:)
    character(len=*) :: funcname

    call AssertEqual(     &
      message = funcname, &
      answer = sol,       &
      check = var,        &
      significant_digits = check_digits, ignore_digits = ignore     )

  end subroutine check2d

end program et_mpi_module_jacobian_test
