!= Module Radiation
!
! Authors::   SUGIYAMA Ko-ichiro
! Version::   $Id: radiation_balance2.f90,v 1.1 2011-02-23 17:24:41 yamasita Exp $
! Tag Name::  $Name:  $
! Copyright:: Copyright (C) GFD Dennou Club, 2006. All rights reserved.
! License::   See COPYRIGHT[link:../../COPYRIGHT]
!
!== Overview
!
!モデルの放射過程を計算するためのパッケージ型モジュール
!具体的には以下の項を計算するための関数を格納する.  
!  * 一様冷却
!
!== Error Handling
!
!== Bugs
!
!== Note
!
!
!== Future Plans
!
!

module Radiation
  !
  !モデルの放射過程を計算するためのパッケージ型モジュール
  !具体的には以下の項を計算するための関数を格納する.  
  !  * 一様冷却
  !

  !モジュール読み込み
  use dc_message, only: MessageNotify

  use GridSet,  only: DimXMin,     & !x 方向の配列の下限
    &                 DimXMax,     & !x 方向の配列の上限
    &                 DimZMin,     & !z 方向の配列の下限
    &                 DimZMax,     & !z 方向の配列の上限
    &                 RegXMin,     & !x 方向の配列の下限
    &                 RegXMax,     & !x 方向の配列の上限
    &                 RegZMin,     & !z 方向の配列の下限
    &                 RegZMax,     & !z 方向の配列の上限
    &                 s_Z,         & !Z 座標軸(スカラー格子点)
    &                 DelZ           !格子間隔
  use TimeSet,  only: DayTime        ! 1 日の長さ [s]
  use basicset, only: xz_ExnerBasicZ, & !エクスナー関数の基本場
    &                 xz_PressBasicZ, & !圧力の基本場
    &                 xz_PotTempBasicZ, & !温位の基本場
    &                 PressSfc,       & !地表面圧力
    &                 CpDry,          & !定圧比熱
    &                 GasRDry,        & !気体定数
    &                 Grav              !重力加速度
  use StorePotTemp,  only: StorePotTempRad, StorePotTempDamp
  
  !暗黙の型宣言禁止
  implicit none

  !private 属性
  private

  !関数を public にする. 
  public Radiation_init
  public xz_RadHeatConst
  public xz_RadHeatBalance
  public xz_NewtonCool

  !変数定義
  real(8)              :: RadHeatRate  = 0.0d0 !一様放射加熱率 [K/day]
  real(8), allocatable :: xz_RadHeight(:,:)    !放射加熱が存在する領域
  real(8)              :: RadHeatRate2  = 0.0d0 !一様放射加熱率 [K/day]
  real(8), allocatable :: xz_RadHeight2(:,:)    !放射加熱が存在する領域
  real(8)              :: HeatWork      !初期時刻における
                                        !単位時間あたりの加熱量(冷却量)
  integer              :: IntHeightUp   !加熱域上限の鉛直座標に対応
                                        !する整数値
  integer              :: IntHeightUp2   !冷却域上限の鉛直座標に対応
                                         !する整数値
  real(8)                  :: RadHeightUp   !放射強制を与える鉛直領域の上限
  real(8)                  :: RadHeightDown !放射強制を与える鉛直領域の下限
  real(8)                  :: RadHeightUp2   !放射強制を与える鉛直領域の上限
  real(8)                  :: RadHeightDown2 !放射強制を与える鉛直領域の下限
  
  !save 属性
!  save RadHeatRate, xz_RadHeight
  save RadHeatRate, xz_RadHeight, RadHeatRate2, xz_RadHeight2, HeatWork
  save IntHeightUp, IntHeightUp2, RadHeightUp, RadHeightDown, RadHeightUp2, RadHeightDown2

contains

!!!------------------------------------------------------------------------!!!
  subroutine Radiation_init(cfgfile)
    !
    !NAMELIST から放射強制の設定を取得
    !

    !暗黙の型宣言禁止
    implicit none

    !入力変数
    character(*), intent(in) :: cfgfile
    real(8)                  :: PressHeightUp   !放射強制領域上限の基本場圧力
                                                !1次補間により算出
!    real(8)                  :: RadHeightUp   !放射強制を与える鉛直領域の上限
!    real(8)                  :: RadHeightDown !放射強制を与える鉛直領域の下限
!    real(8)                  :: RadHeightUp2   !放射強制を与える鉛直領域の上限
!    real(8)                  :: RadHeightDown2 !放射強制を与える鉛直領域の下限
    integer                  :: k             !ループ変数


    ! NAMELIST から情報を取得
    NAMELIST /radiation/ RadHeatRate, RadHeightUp, RadHeightDown, RadHeatRate2, RadHeightUp2, RadHeightDown2

    open (10, FILE=cfgfile)
    read(10, NML=radiation)
    close(10)

    allocate( xz_RadHeight(DimXMin:DimXMax, DimZMin:DimZMax) )
    allocate( xz_RadHeight2(DimXMin:DimXMax, DimZMin:DimZMax) )

    ! IntHeightUp の特定
    do k = DimZMin, DimZMax
      if ( (RadHeightUp - DelZ <= s_Z(k)) .and. (s_Z(k) < RadHeightUp) ) then
        IntHeightUp = k
      else if ( (RadHeightUp2 - DelZ <= s_Z(k)) .and. (s_Z(k) < RadHeightUp2) ) then
        IntHeightUp2 = k
      end if
    end do

    ! PressHeightUp の算出
    PressHeightUp =  xz_PressBasicZ(1,IntHeightUp) +  &
     & ( xz_PressBasicZ(1,IntHeightUp + 1) - xz_PressBasicZ(1,IntHeightUp) ) &
     & * ( RadHeightUp - s_Z(IntHeightUp) ) / DelZ


    ! HeatWork の算出
    HeatWork = CpDry * RadHeatRate * ( PressSfc - PressHeightUp ) / Grav

    ! 放射強制が存在する領域の設定
    ! RadHeightDown < s_Z < RadHeightUp の範囲では値が 1 となる
    ! 係数を用意する.
    !
    xz_RadHeight = 1.0d0    
    xz_RadHeight2 = 1.0d0    

    do k = DimZMin, DimZMax
      if ( s_Z(k) <= RadHeightDown  ) then
        xz_RadHeight(:,k) = 0.0d0 
      elseif( s_Z(k) >= RadHeightUp ) then
        xz_RadHeight(:,k) = 0.0d0 
      end if
    end do

    do k = DimZMin, DimZMax
      if ( s_Z(k) <= RadHeightDown2  ) then
        xz_RadHeight2(:,k) = 0.0d0 
      elseif( s_Z(k) >= RadHeightUp2 ) then
        xz_RadHeight2(:,k) = 0.0d0 
      end if
    end do

    

    call MessageNotify( "M", &
      & "Radiation", "RadHeatRate = %f", d=(/RadHeatRate/))
    call MessageNotify( "M", &
      & "Radiation", "RadHeightUp = %f", d=(/RadHeightUP/))
    call MessageNotify( "M", &
      & "Radiation", "RadHeightDown= %f", d=(/RadHeightDown/))
    call MessageNotify( "M", &
      & "Radiation", "RadHeatRate2 = %f", d=(/RadHeatRate2/))
    call MessageNotify( "M", &
      & "Radiation", "RadHeightUp2 = %f", d=(/RadHeightUP2/))
    call MessageNotify( "M", &
      & "Radiation", "RadHeightDown2 = %f", d=(/RadHeightDown2/))
    call MessageNotify( "M", &
      & "Radiation", "PressHeightUp = %f", d=(/PressHeightUp/))
    
  end subroutine Radiation_init


!!!------------------------------------------------------------------------!!!
  function xz_RadHeatConst(xz_Exner)
    !
    ! 温位の放射強制項. 
    ! 地表面から RadHeight で指定された高度までの間で一様放射冷却を与える. 
    ! エクスナー関数は基本場で与える. 
    
    !暗黙の型宣言を禁止
    implicit none

    !変数定義
    real(8), intent(in)   :: xz_Exner(DimXMin:DimXMax, DimZMin:DimZMax)
                                       !エクスナー関数の擾乱場
    real(8)               :: xz_RadHeatConst(DimXMin:DimXMax, DimZMin:DimZMax)
                                       !放射強制

!    xz_RadHeatConst = &
!      & xz_RadHeight * RadHeatRate  &
!      & / ( ( xz_ExnerBasicZ + xz_Exner ) * DayTime )

    xz_RadHeatConst = &
      & xz_RadHeight * RadHeatRate  &
      & / ( ( xz_ExnerBasicZ + xz_Exner ) * DayTime ) &
      & + xz_RadHeight2 * RadHeatRate2  &
      & / ( ( xz_ExnerBasicZ + xz_Exner ) * DayTime )

    call StorePotTempRad( xz_RadHeatConst )
    
  end function xz_RadHeatConst


!!!------------------------------------------------------------------------!!!
  function xz_RadHeatBalance(xz_ExnerBasicZ, xz_PotTempBasicZ, xz_Exner, xz_PotTemp)
    !
    ! 温位の放射強制項. 
    ! 地表面から RadHeight で指定された高度までの間で空間的に一様な加熱, 
    ! RadHeight から RadHeight2 までの間で空間的な一様な冷却を与える. 
    ! 放射強制全体として加熱と冷却がバランスするように時々刻々一様加熱率
    ! および一様冷却率を変化させる. 
    ! この際, ある時刻における各々の加熱量と冷却量は初期の加熱量と冷却量
    ! 等しくなるように調節する. 

    !暗黙の型宣言を禁止
    implicit none

    !変数定義
    real(8), intent(in)   :: xz_ExnerBasicZ(DimXMin:DimXMax, DimZMin:DimZMax)
    real(8), intent(in)   :: xz_Exner(DimXMin:DimXMax, DimZMin:DimZMax)
    real(8), intent(in)   :: xz_PotTempBasicZ(DimXMin:DimXMax, DimZMin:DimZMax)
    real(8), intent(in)   :: xz_PotTemp(DimXMin:DimXMax, DimZMin:DimZMax)
    real(8)               :: xz_RadHeatBalance(DimXMin:DimXMax, DimZMin:DimZMax)                                       !放射強制
    real(8)               :: xz_DensSum(DimXMin:DimXMax, DimZMin:DimZMax) 
                                        !密度(基本場成分と擾乱成分の和)
    real(8)               :: z_DensXmean(DimZMin:DimZMax)
                                        !密度(水平平均)
    real(8)               :: HeatRatio  !初期の加熱率とある時刻の加熱率の比
    real(8)               :: CoolRatio  !初期の冷却率とある時刻の冷却率の比
    real(8)               :: HeatSum    !ある時刻での単位時間当たりの加熱量
    real(8)               :: CoolSum    !ある時刻での単位時間当たりの冷却量
    integer               :: k

    ! 密度の算出
    xz_DensSum = PressSfc &
      & * (xz_ExnerBasicZ + xz_Exner)**( (CpDry - GasRDry)/GasRDry ) &
      & / (GasRDry * (xz_PotTempBasicZ + xz_PotTemp ) )

    ! 密度の水平平均の算出
    z_DensXmean = sum( xz_DensSum, 1) / real(DimXMax - DimXMin + 1)

    HeatSum = 0.0d0
    CoolSum = 0.0d0

    ! ある時刻での加熱量を計算
!    do k = DimZmin, IntHeightUp - 1
    do k = RegZmin + 1, IntHeightUp - 1
     HeatSum = HeatSum + 0.5d0 * DelZ * CpDry * RadHeatRate * &
       & ( z_DensXmean(k) + z_DensXmean(k+1) )
    end do

    HeatSum = HeatSum + 0.5d0 * CpDry * RadHeatRate * &
      & ( 2.0d0 * z_DensXmean(RegZMin+1) * s_Z(RegZMin+1) - &
      &   (z_DensXmean(RegZMin+2) - z_DensXmean(RegZMin+1) ) &
      &   * s_Z(RegZMin+1) * s_Z(RegZMin+1) / DelZ &
      & + 2.0d0 * z_DensXmean(IntHeightUp) * &
      &   (RadHeightUp - s_Z(IntHeightUp)) - &
      &   ( z_DensXmean(IntHeightUp - 1) - z_DensXmean(IntHeightUp) ) & 
      &   * (RadHeightUp - s_Z(IntHeightUp)) &
      &   * (RadHeightUp - s_Z(IntHeightUp)) / DelZ  )

    ! ある時刻での冷却量を計算
    do k = IntHeightUp + 1, IntHeightUp2 - 1
     CoolSum = CoolSum + 0.5d0 * DelZ * CpDry * RadHeatRate2 * &
       & ( z_DensXmean(k) + z_DensXmean(k+1) )
    end do

    CoolSum = CoolSum + 0.5d0 * CpDry * RadHeatRate2 * &
      & ( 2.0d0 * z_DensXmean(IntHeightUp + 1) * &
      &   ( s_Z(IntHeightUp+1) - RadHeightDown2 ) - &
      &   (z_DensXmean(IntHeightUp+2) - z_DensXmean(IntHeightUp+1) ) &
      &   * ( s_Z(IntHeightUp+1) - RadHeightDown2 )  &
      &   * ( s_Z(IntHeightUp+1) - RadHeightDown2 ) / DelZ &
      & + 2.0d0 * z_DensXmean(IntHeightUp2) * &
      &   (RadHeightUp2 - s_Z(IntHeightUp2)) - &
      &   ( z_DensXmean(IntHeightUp2 - 1) - z_DensXmean(IntHeightUp2) ) & 
      &   * (RadHeightUp2 - s_Z(IntHeightUp2))  &
      &   * (RadHeightUp2 - s_Z(IntHeightUp2)) / DelZ )

    ! 加熱量及び冷却量の変化の比を算出
    HeatRatio = HeatWork / HeatSum

    CoolRatio = - HeatWork / CoolSum

    xz_RadHeatBalance = &
      & xz_RadHeight * HeatRatio * RadHeatRate  &
      & / ( xz_ExnerBasicZ  * DayTime ) &
      & + xz_RadHeight2 * CoolRatio * RadHeatRate2  &
      & / ( xz_ExnerBasicZ  * DayTime )

    call StorePotTempRad( xz_RadHeatBalance )
    
  end function xz_RadHeatBalance
  
  
  
!!!------------------------------------------------------------------------!!!
  function xz_NewtonCool(xz_PotTemp)
    !
    ! 温位の放射強制項. 
    ! 地表面から RadHeight で指定された高度までの間で一様放射冷却を与える. 
    ! 
    
    !暗黙の型宣言を禁止
    implicit none

    !変数定義
    real(8), intent(in)   :: xz_PotTemp(DimXMin:DimXMax, DimZMin:DimZMax)
                                       !温位の擾乱場
    real(8)               :: xz_NewtonCool(DimXMin:DimXMax, DimZMin:DimZMax)
                                       !放射強制
    real(8)               :: xz_PotTempMean(DimXMin:DimXMax, DimZMin:DimZMax)
                                       !温位擾乱の東西平均
    real(8)               :: EFTime    !放射緩和時間
    integer               :: k

    !放射緩和時間は 5 日
    EFTime = 5.0d0 * DayTime  
    
    do k = DimZMin, DimZMax
      xz_PotTempMean(:,k) = sum( xz_PotTemp(:,k) ) / real(DimXMax - DimXMin + 1)
    end do
    
    xz_NewtonCool = - xz_PotTempMean / EFTime 
    
    call StorePotTempDamp( xz_NewtonCool )

  end function xz_NewtonCool
  
end module Radiation
