!----------------------------------------------------------------------
!     Copyright (c) 2016 Shin-ichi Takehiro. All rights reserved.
!----------------------------------------------------------------------
!
!表題  tee_mpi_module テストプログラム (境界値問題, トロイダル磁場, Tau 法)
!
!履歴  2016/09/21  竹広真一
!
program tee_mpi_module_tormagbcgrid_test

  use dc_message, only : MessageNotify
  use dc_test, only : AssertEqual
  use tee_mpi_module
  use mpi
  implicit none

 !---- 空間解像度設定 ----
  integer, parameter :: im=32, jm=32, km=16       ! 格子点の設定(X,Y)
  integer, parameter :: lm=10, mm=10, nm=16       ! 切断波数の設定(X,Y)

 !---- 変数 ----
  real(8), allocatable :: zvx_Tormag(:,:,:)      ! 格子データ
  real(8), allocatable :: zvx_Tormag_orig(:,:,:) ! 格子データ

  real(8), allocatable :: vx_BoundaryTop(:,:)    ! 格子データ
  real(8), allocatable :: vx_BoundaryBtm(:,:)    ! 格子データ

  real(8), allocatable :: tef_Tormag(:,:,:)      ! スペクトルデータ

  integer            :: l=2, m=5
  integer            :: np, ip, ierr
  
 !---- 座標変数など ----
  real(8), parameter :: xmin = 0.0d0, xmax=2.0d0
  real(8), parameter :: ymin = 0.0d0, ymax=2.0d0
  real(8), parameter :: zmin = -1.0d0, zmax=1.0d0

  real(8), parameter :: pi=3.1415926535897932385D0

  ! 判定誤差設定
  integer, parameter :: check_digits = 11
  integer, parameter :: ignore = -12

  call MessageNotify('M','tee_mpi_module_TormagbcGrid_test', &
       'tee_mpi_module toroidal mag. field B.C. subruoutine tests')

 !---------------- MPI スタート ---------------------
  call MPI_INIT(IERR)
  call MPI_COMM_RANK(MPI_COMM_WORLD,IP,IERR)
  call MPI_COMM_SIZE(MPI_COMM_WORLD,NP,IERR)

 !---------------- 座標値の設定 ---------------------
  ! スペクトル初期化
  call tee_mpi_initial(im,jm,km,lm,mm,nm,xmin,xmax,ymin,ymax,zmin,zmax) 

  allocate(zvx_Tormag(0:km,jc(ip),0:im-1))      ! 格子データ
  allocate(zvx_Tormag_orig(0:km,jc(ip),0:im-1)) ! 格子データ

  allocate(vx_BoundaryTop(jc(ip),0:im-1))     ! 格子データ
  allocate(vx_BoundaryBtm(jc(ip),0:im-1))     ! 格子データ

  allocate(tef_Tormag(0:nm,-mm:mm,2*lc(ip)))      ! スペクトルデータ
  
 !-------------------BC-DD(Grid) ----------------------
  zvx_Tormag = sin(l*pi*zvx_X) * sin(m*pi*zvx_Y) * zvx_Z
  zvx_Tormag_orig = zvx_Tormag
  vx_BoundaryTop = 0.0D0
  vx_BoundaryBtm = 0.0D0

  tef_Tormag = tef_zvx(zvx_Tormag)
  call tef_TormagBoundariesGrid(tef_Tormag)
  zvx_Tormag = zvx_tef(tef_Tormag)

  call AssertEqual(&
    message='tef_TormagBoundariesGrid [internal]',&
    answer = zvx_Tormag_orig(1:km-1,:,:),                         &
    check = zvx_Tormag(1:km-1,:,:),                               &
    significant_digits = check_digits, ignore_digits = ignore     &
    )
  call AssertEqual(&
    message='tef_TormagBoundariesGrid [Top]',&
    answer = zvx_Tormag(0,:,:),                                   &
    check = vx_BoundaryTop,                                       &
    significant_digits = check_digits, ignore_digits = ignore     &
    )
  call AssertEqual(&
    message='tef_TormagBoundariesGrid [Bottom]', &
    answer = zvx_Tormag(km,:,:),                                  &
    check = vx_BoundaryBtm,                                       &
    significant_digits = check_digits, ignore_digits = ignore     &
    )

  call MPI_FINALIZE(IERR)

  call MessageNotify('M','tee_mpi_module_TormagbcGrid_test', &
       'tee_mpi_module toroidal mag. field B.C. subruoutine tests succeeded!')

end program tee_mpi_module_tormagbcgrid_test
