!----------------------------------------------------------------------
!     Copyright (c) 2016 Shin-ichi Takehiro. All rights reserved.
!----------------------------------------------------------------------
!
!表題  ua_mpi_module_svpack テストプログラム :: 補間関数のテスト
!
!履歴  2016/08/15  竹広真一
!
program ua_mpi_module_svpack_interplate_test

  use dc_message, only : MessageNotify
  use dc_test, only : AssertEqual
  use ua_mpi_module_svpack
  use mpi
  implicit none

  integer, parameter :: im=32, jm=16, nm=10, km=3

  real(8), allocatable ::  xyb_data(:,:,:)
  real(8), allocatable ::  ua_data(:,:)
  
  ! 判定誤差設定
  integer, parameter :: check_digits = 10
  integer, parameter :: ignore = -11

  real(8) :: Alon
  real(8) :: Alat
  real(8), dimension(km) :: a_data_sol
  real(8) :: pi
  integer :: iproc, np, ierr

 !---------------- MPI スタート ---------------------
  call MPI_INIT(IERR)
  call MPI_COMM_RANK(MPI_COMM_WORLD,IPROC,IERR)
  call MPI_COMM_SIZE(MPI_COMM_WORLD,NP,IERR)

  pi = atan(1.0D0)*4.0D0
  Alon = pi/5 ; Alat = pi/3

  call ua_mpi_Initial( nm, im, jm, km )

  call MessageNotify('M','ua_Interpolate00_mpi_module_svpack_test', &
                         'ua_mpi_module_svpack interpolate(00) tests') 

  allocate(xyb_data(0:im-1,jm,kc))
  allocate(ua_data(nc,km))
  
  !---- Y_1^* のテスト ----
  if ( kp_kl(1) /= 0 ) &
       xyb_data(:,:,kp_kl(1)) = sqrt(3.0D0)*sin(xy_Lat)            ! Y_1^0
  a_data_sol(1) = sqrt(3.0D0)*sin(ALat)

  if ( kp_kl(2) /= 0 ) &
       xyb_data(:,:,kp_kl(2)) = sqrt(3.0D0/2)*cos(xy_Lat)*cos(xy_Lon)     ! Y_1^1
  a_data_sol(2) = sqrt(3.0D0/2)*cos(ALat)*cos(ALon)

  if ( kp_kl(3) /= 0 ) &
       xyb_data(:,:,kp_kl(3))   = -sqrt(3.0D0)*cos(xy_Lat)*sin(xy_Lon)    ! Y_1^{-1}
  a_data_sol(3) = -sqrt(3.0D0)*cos(ALat)*sin(ALon)

  ua_data = ua_xyb(xyb_data)

  call AssertEqual(&
    message='a_Interpolate_ua with Y_1^*',                        &
    answer = a_Interpolate_ua(ua_data,alon,alat),                 &
    check =  a_data_sol,                                          &
    significant_digits = check_digits, ignore_digits = ignore     &
    )

  !---- Y_2^* のテスト ----
  if ( kp_kl(1) /= 0 ) &
       xyb_data(:,:,kp_kl(1)) = sqrt(5.0D0)*(3.0/2*sin(xy_Lat)**2-1/2.0)            ! Y_2^0
  a_data_sol(1) = sqrt(5.0D0)*(3.0/2*sin(alat)**2-1.0/2)
  if ( kp_kl(2) /= 0 ) &
       xyb_data(:,:,kp_kl(2)) = sqrt(5.0D0/6)*3.0*sin(xy_Lat)*cos(xy_Lat) * cos(xy_Lon)!Y_2^1
  a_data_sol(2) = sqrt(5.0D0/6)*3.0*sin(ALat)*cos(ALat) * cos(ALon)
  if ( kp_kl(3) /= 0 ) &
       xyb_data(:,:,kp_kl(3)) = -sqrt(5.0D0/24)*3.0*cos(xy_Lat)**2*sin(2*xy_Lon) ! Y_2^-2
  a_data_sol(3) = -sqrt(5.0D0/24)*3.0*cos(ALat)**2*sin(2*ALon)

  ua_data = ua_xyb(xyb_data)

  call AssertEqual(&
    message='a_Interpolate_ua with Y_2^*',                        &
    answer = a_Interpolate_ua(ua_data,alon,alat),                 &
    check =  a_data_sol,                                          &
    significant_digits = check_digits, ignore_digits = ignore     &
    )

  !---- 一般的な関数のテスト ----
  if ( kp_kl(1) /= 0 ) &
       xyb_data(:,:,kp_kl(1)) = cos(2*xy_Lon-pi/3) &
                       *(sin(xy_Lat)-1)**2*(sin(xy_Lat)-0.5)*(sin(xy_Lat)+1)
  a_data_sol(1) = cos(2*ALon-pi/3) &
       *(sin(ALat)-1)**2*(sin(ALat)-0.5)*(sin(ALat)+1)
  if ( kp_kl(2) /= 0 ) &
       xyb_data(:,:,kp_kl(2)) = sin(2*xy_Lon-pi/3)*(sin(xy_Lat)-1)**2*(sin(xy_Lat)+1)**2
  a_data_sol(2) = sin(2*aLon-pi/3)*(sin(aLat)-1)**2*(sin(aLat)+1)**2
  if ( kp_kl(3) /= 0 ) &
       xyb_data(:,:,kp_kl(3)) = sin(2*xy_Lon+pi/3)*(sin(xy_Lat)-1)**3*(sin(xy_Lat)+1)
  a_data_sol(3) = sin(2*aLon+pi/3)*(sin(aLat)-1)**3*(sin(aLat)+1)

  ua_data = ua_xyb(xyb_data)

  call AssertEqual(&
    message='a_Interpolate_ua with a general function',           &
    answer = a_Interpolate_ua(ua_data,alon,alat),                 &
    check =  a_data_sol,                                          &
    significant_digits = check_digits, ignore_digits = ignore     &
    )

  call MessageNotify('M','ua_Interpolate00_mpi_module_svpack_test', &
       'ua_mpi_module_svpack interpolate(00) tests succeeded') 

 !------ MPIの終了 ------

  call MPI_FINALIZE(IERR)

end program ua_mpi_module_svpack_interplate_test