!--------------------------------------------------------------------------
! Copyright (C) 2002--2005 SPMODEL Development Group. All rights reserved.
!--------------------------------------------------------------------------
! Sample program for SPML(based on gt4f90io and ISPACK)  
!
!    2002/09/25 S.Takehiro
!    2004/01/26 M.Odaka
!    2004/06/17 M.Odaka
!    2005/03/25 S.Takehiro
!    2026/07/08 S.Takehiro for et_module
! 
! Solving 2-D Boussinesq fluid system 
!     d\zeta/dt 
!        + + J(\psi,\zeta) + g/\rho_0 d\rho/dx - nu\lapla\zeta = 0,
!
!     \nabla\psi = \zeta
!
!     d\rho/dt + J(\psi,\rho) = D\nabla\rho
!
!     psi = zeta = d\rho/dy = 0 at y=0,1
!
program gravcurrent1

  use et_module
  use gtool_history
  implicit none

  !---- 空間解像度設定 ----
!!$  integer, parameter :: km=42 , lm=42         ! 切断波数の設定(X,Y)
!!$  integer, parameter :: im=128, jm=64         ! 格子点の設定(X,Y)
  integer, parameter :: km=85 , lm=85          ! 切断波数の設定(X,Y)
  integer, parameter :: im=256, jm=128         ! 格子点の設定(X,Y)

  !---- 変数 ----
  real(8)            :: yx_Psi(0:jm,0:im-1)     ! 格子データ(流線)
  real(8)            :: yx_Zeta(0:jm,0:im-1)    ! 格子データ(渦度)
  real(8)            :: yx_Rho(0:jm,0:im-1)     ! 格子データ(密度)

  real(8)            :: et_Psi(-km:km,0:lm)     ! スペクトルデータ(流線)
  real(8)            :: et_ZetaA(-km:km,0:lm)   ! スペクトルデータ(渦度,t+1)
  real(8)            :: et_RhoA(-km:km,0:lm)    ! スペクトルデータ(密度,t+1)

  real(8)            :: et_ZetaB(-km:km,0:lm)   ! スペクトルデータ(渦度,t)
  real(8)            :: et_RhoB(-km:km,0:lm)    ! スペクトルデータ(密度,t)

  real(8)            :: x_RhoBndry(0:im-1,2)    ! 境界値
  real(8)            :: e_RhoBndry(-km:km,2)    ! 境界値

  real(8)            :: e_ZetaBndry(-km:km,2)    ! 境界値


  !---- 座標変数など ----
  real(8), parameter :: xmin=0.0, xmax=120.0    ! 領域範囲(X 方向) 
  real(8), parameter :: ymin=0.0, ymax=20.0     ! 領域範囲(Y 方向) 

  !---- 時間積分パラメター ----
!!$  real(8), parameter :: dt=1e-4                  ! 時間ステップ間隔
!!$  integer, parameter :: nt=300000, ndisp=10000   ! 時間積分数, 表示ステップ
  real(8), parameter :: dt=2e-5                  ! 時間ステップ間隔
  integer, parameter :: nt=1500000, ndisp=50000   ! 時間積分数, 表示ステップ

  !---- 物理パラメター ----
  real(8), parameter :: Grav=9.8d2               ! 重力加速度
  real(8), parameter :: Visc=1.0d-1              ! 動粘性係数
  real(8), parameter :: Diff=1.0d-5              ! 拡散係数

  real(8), parameter :: Rho0     = 1.0d0         ! 平均密度
  real(8), parameter :: deltaRho = 0.001         ! 密度差
  real(8), parameter :: Ax0   = 10.0             ! 密度擾乱の大きさ(X)
  real(8), parameter :: Sigma = 2.0              ! 密度擾乱の遷移層の幅

  integer            :: it = 0                   ! DO 変数
  real(8)            :: X1, X2

  !---------------- 座標値の設定 ---------------------
  call et_initial(im,jm,km,lm,xmin,xmax,ymin,ymax)      ! ISPACK初期化

  !------------------- 初期値設定 ----------------------

  ! 流速分布
  yx_Psi = 0.0  ; et_Psi   = et_yx(yx_Psi)
  yx_Zeta = 0.0 ; et_ZetaA  = et_yx(yx_Zeta) ; et_ZetaB = et_ZetaA

  ! 密度分布
  X1 = (xmin+xmax)/2 - Ax0
  X2 = (xmin+xmax)/2 + Ax0
  yx_Rho =  Rho0  + deltaRho * (   tanh((yx_X-X1)/Sigma) &
                  - tanh((yx_X-X2)/Sigma) )/2
  et_RhoA = et_yx(yx_Rho) ; et_RhoB = et_RhoA


  !------------------- 境界値設定 ----------------------
  x_RhoBndry(:,1) = 0.0D0
  x_RhoBndry(:,2) = 0.0D0
  e_RhoBndry(:,1) = e_x(x_RhoBndry(:,1))
  e_RhoBndry(:,2) = e_x(x_RhoBndry(:,2))

  e_ZetaBndry = 0.0D0
  
  !------------------- 出力設定 ----------------------
  call output_gtool_init                              ! ヒストリー初期化
  call output_gtool                                   ! 初期値出力

  !------------------- 時間積分 ----------------------
  do it=1,nt
     et_RhoA = et_RhoB + &
          dt*( - et_Jacobian_et_et(et_Psi,et_RhoB) &
          + Diff * et_Lapla_et(et_RhoB) )

     call et_Boundaries(et_RhoA,e_RhoBndry,cond='NN')

     et_ZetaA = et_ZetaB +                               &
          dt*( - et_Jacobian_et_et(et_Psi,et_ZetaB)      &
          - Grav/Rho0 * et_yx(yx_et(et_Dx_et(et_RhoB))) &
          + Visc * et_lapla_et(et_zetaB) )

     call et_boundaries(et_ZetaA,e_ZetaBndry,cond='DD')

     et_Psi = et_LaplaInv_et(et_ZetaA)

     et_ZetaB = et_ZetaA
     et_RhoB  = et_RhoA

     if(mod(it,ndisp) .eq. 0)then                        ! 出力
        call output_gtool
     endif
  enddo

  call output_gtool_close
  stop

contains
  subroutine output_gtool_init
    call HistoryCreate( &                               ! ヒストリー作成
         file='gravcurrent1.nc', title='Gravity current', &
         source='Sample program of gtool_history/gtool5', &
         institution='GFD_Dennou Club davis/spmodel project',&
         dims=(/'x','y','t'/), dimsizes=(/im,jm+1,0/),    &
         longnames=(/'X-coordinate','Y-coordinate','time        '/),&
         units=(/'cm','cm','s '/),                           &
         origin=0.0, interval=real(ndisp*dt) )

    call HistoryPut('x',x_X)                                   ! 変数出力
    call HistoryAddattr('x','topology','circular')             ! 周期属性
    call HistoryAddattr('x','modulo',xmax-xmin)                ! 周期属性
    call HistoryPut('y',y_Y)                                   ! 変数出力

    call HistoryAddVariable( &                          ! 変数定義
         varname='psi', dims=(/'x','y','t'/), & 
         longname='stream function', units='1', xtype='double')
    call HistoryAddVariable( &                          ! 変数定義
         varname='zeta', dims=(/'x','y','t'/), & 
         longname='voticity', units='1', xtype='double')
    call HistoryAddVariable( &                          ! 変数定義
         varname='rho', dims=(/'x','y','t'/), & 
         longname='density', units='g/cm3', xtype='double')
  end subroutine output_gtool_init

  subroutine output_gtool
    yx_Psi  = yx_et(et_Psi)
    yx_Zeta = yx_et(et_ZetaA)
    yx_Rho = yx_et(et_RhoA)

    write(6,*) 'it = ',it
    call HistoryPut('t',dt*it)
    call HistoryPut('psi',transpose(yx_Psi))
    call HistoryPut('zeta',transpose(yx_Zeta))
    call HistoryPut('rho',transpose(yx_Rho))
  end subroutine output_gtool

  subroutine output_gtool_close
    call HistoryClose
  end subroutine output_gtool_close

end program gravcurrent1
