!= Sample program for gt4_history/gt4f90io
!
! * 2007/06/25 M.Odaka
! * 2006/10/25 Y.Morikawa
! * 2003/08/21 M.Odaka
! * 2001/02/27 S.Takehiro
!
! Solving diffusion equation
! \[
!     du/dt = \kappa d^2 u/dx^2
! \]
! for giving values of $u$ at $x=[0,1]$.
!
program diffusion_5

  use gt4_history                                   ! モジュール指定
  use dc_types, only : DP                           ! モジュール指定
  use dc_clock, only : CLOCK, Create, Close, Start, &
    &            Stop, Result, Predict, operator(+) ! モジュール指定

  integer, parameter     :: nx=30                   ! グリッド数
  integer, parameter     :: nt=200                  ! 時間ステップ数
  integer, parameter     :: ndisp=10                ! 出力間隔
  real(DP), parameter    :: dx=1.0/(nx-1)           ! グリッド間隔
  real(DP), parameter    :: dt=0.0005               ! 時間間隔
  real(DP), dimension(nx):: x=(/(dx*(i-1),i=1,nx)/) ! 座標変数
  real(DP), dimension(nx):: temp                    ! 温度
  real(DP), parameter    :: kappa=1.0               ! 熱拡散係数
  type(CLOCK)            :: clock_init, clock_roop  ! CPU 時間計測用変数

  call Create( clk = clock_init, &                  ! 初期化
    &          name = 'initialization' )
  call Create( clk = clock_roop, &                  ! 初期化
    &          name = 'time-integration' )

  call Start( clk = clock_init )                    ! CPU 時間計測開始

  tinit = 0.0                                       ! 初期時刻設定

  temp = exp(-((x-0.5)/0.1)**2)                     ! 初期値設定

  call HistoryCreate( &                             ! ヒストリー作成
    & file='diffusion_5.nc', title='Diffusion equation', &
    & source='Sample program of gt4_history/gt4f90io',   &
    & institution='GFD_Dennou Club davis project',       &
    & dims=(/'x','t'/), dimsizes=(/nx,0/),               &
    & longnames=(/'X-coordinate','time        '/),       &
    & units=(/'m','s'/),                                 &
    & origin=real(tinit), interval=real(ndisp*dt) )

  call HistoryPut('x',x)                            ! 次元変数出力

  call HistoryAddVariable( &                        ! 変数定義
    & varname='temp', dims=(/'x','t'/), &
    & longname='temperature', units='K', xtype='double')

  call HistoryAddAttr('temp','gt_graph_tick_all',1)
  call HistoryAddAttr('temp','gt_graph_contour_spacing',(/0.0,1.0,0.01/))
  call HistoryAddAttr('temp','+gt_user_davis_kappa',kappa)

  call HistoryPut('temp',temp)                      ! 変数出力

  call Stop( clk = clock_init )                     ! CPU 時間計測終了

  do it=1,nt
    call Start ( clk = clock_roop )                 ! CPU 時間計測開始

    temp(2:nx-1) = temp(2:nx-1) &                   ! 時間積分
      & + kappa*(temp(3:nx)-2*temp(2:nx-1)+temp(1:nx-2))/dx**2*dt

    if ( mod(it,ndisp) == 0 ) then
      call HistoryPut('temp',temp)                  ! 変数出力
    endif

    call Stop( clk = clock_roop )                   ! CPU 時間計測終了
    call Predict( clk = clock_init + clock_roop, &  ! 残り時間の予測
      &            progress = real(it)/real(nt) )

  end do

  call HistoryClose

  call Result( clks = (/clock_init, clock_roop/), & ! 全 CPU 時間の表示
    &          total_auto = .true. )
  call Close( clk = clock_init )                    ! 後処理
  call Close( clk = clock_roop )                    ! 後処理

  stop
end program diffusion_5

Gtool4 Development Group / GFD Dennou Staff