gtool_history の使い方ガイド

gtool_history モジュールは, 数値モデルの結果を gtool4 形式で出力するためのインターフェースです. おもに時間積分の結果を等時間間隔で出力することを念頭においてます. このモジュールを用いれば, Fortran90 で書かれたプログラムの計算結果を gtool4 データ形式で出力することが簡単に実現できます. 以下では簡単なプログラムを例に, gtool_history モジュールの使い方を説明します.

準備 : 必要なもの

gtool4/Fortarn90 ライブラリ取得の仕方, インストールの方法などはこちらから.
メインプログラム Fortran90 が望ましいです. Fortran77 のプログラムの場合には, 機能が制限された別のサブルーチン群を用いる必要があります.

データ出力のための最低限の設定

このプログラムは 1 次元の熱伝導問題を解くものです. 出力結果は write 文で行われているだけです. これに対して gtool_history を適用したのが以下のプログラムです. 赤字(カラーがでない場合はボールド)が gtool_history に関係している箇所です.


! Sample program for gtool_history/gtool4
! 
! Solving diffusion equation 
!     du/dt = d^2 u/dx^2
! for giving values of u at x=0 and 1. 
!
program diffusion
  
  use gtool_history                                          ! モジュール指定
  
  integer, parameter              :: nx=30                   ! グリッド数
  integer, parameter              :: nt=200                  ! 時間ステップ数
  integer, parameter              :: ndisp=10                ! 出力間隔
  double precision, parameter     :: dx=1.0/(nx-1)           ! グリッド間隔
  double precision, parameter     :: dt=0.0005               ! 時間間隔
  double precision, dimension(nx) :: x=(/(dx*(i-1),i=1,nx)/) ! 座標変数
  double precision, dimension(nx) :: temp                    ! 温度
  double precision, parameter     :: kappa=1.0               ! 熱拡散係数

  temp = exp(-((x-0.5)/0.1)**2)                              ! 初期値設定
  
  call HistoryCreate( &                                      ! ヒストリー作成
       file='diffusion.nc', title='Diffusion equation', &
       source='Sample program of gtool_history/gtool4', &
       institution='GFD_Dennou Club davis project',     &
       dims=(/'x','t'/), dimsizes=(/nx,0/),             &
       longnames=(/'X-coordinate','time        '/),     &
       units=(/'m','s'/),                               &
       origin=0.0, interval=real(ndisp*dt) )

  call HistoryPut('x',x)                                     ! 次元変数出力

  call HistoryAddVariable( &                                 ! 変数定義
       varname='temp', dims=(/'x','t'/), & 
       longname='temperature', units='K', xtype='double')

  call HistoryPut('temp',temp)                               ! 変数出力
  
  do it=1,nt
     temp(2:nx-1) = temp(2:nx-1) &                           ! 時間積分
          +kappa*(temp(3:nx)-2*temp(2:nx-1)+temp(1:nx-2))/dx**2*dt

     if ( mod(nt,ndisp) .eq. 0 ) then
        
	call HistoryPut('temp',temp)                         ! 変数出力
	
     endif
  enddo

  call HistoryClose
  stop
end program diffusion

このプログラムを diffusion.f90 という名前で保存し, 実際にコンパイルして実行してみましょう. コンパイルの仕方は環境によって異なります. 例えば Linux 上の Futjitsu Fortran95 コンパイラの場合には

   % frt -Am -I/usr/local/lib/modules -L/usr/local/lib -lgtool4 diffusion.f90

といった具合です . a.out という実行ファイルができますので

   % a.out

と実行させると, diffusion.nc という gtool4 データ形式のファイルが作成されます. NetCDF のコマンド ncdump を用いて中身を見てみましょう.

   % ncdump diffusion.nc | more

とすると, 変数の値だけでなく様々な情報が付加されている様子を見ることができます.

描画は gtview コマンドを用いて簡単に行えます.

   % gtview diffusion.nc

とすると, 時間--空間面上での温度の変化の様子が表示されます.

   % gtview diffusion.nc@temp,t=1

とすると, 時刻 1 での温度分布が表示されます.

より詳しい gtview の使い方についてはこちらのドキュメントを参照してください.

使われているサブルーチンの説明

例題のプログラムにおいて追加された gtool_history モジュールサブルーチンが行っていることを大まかに説明します. より詳しい説明はレファレンスマニュアルを参照してください(まだない).

use gtool_history

モジュールの使用を宣言します. Fortran90 メインプログラムの先頭にいれましょう.

CALL HistoryCreate(...)

gtool4 データ出力の初期設定を行います. 各引数の意味は次のとおりです.

file は出力するファイルの名前を指定します.
title, source, institution は生成する gtool4 データについての一般的な情報を書き込みます
title はデータ全体の表題, source はデータを作成する際の手段を書いておきます. モデル計算の出力ならばモデルの名前を書けばよいでしょう. institution はファイルを最終的に変更した人あるいは組織などを示す項目です.
dims, dimsizes, longnames, unitsは次元に関する情報を指定しています.
サンプルプログラムでは複数の次元を設定していますので, それぞれの項目を配列として与えています.
- dims は次元の名前を定義します.
  gtool_history ではこの名前を用いて次元を参照あるいは指定したりすることになります.
- dimsizes はそれぞれの次元の大きさを指定しています.
  0 は延長可能な次元であることを意味します. 時間積分計算の場合には, 時間の次元をこのような変数に指定すればよいでしょう.
- longnames は長い名前を指定します.
  gtview 等の描画の際に軸のタイトルとして用いられることになります.
- units は各次元の単位です.
  無次元の場合には '1' を単位として指定してください.
origin, interval は出力するデータの時間設定に関連する項目です.
- origin は時間の原点であり, HistoryPut により変数を最初に出力するときの時間を指定します.
- interval は出力時間間隔を示しています. 同じ変数に対して HistoryPut を再度呼んだときに自動的に時間変数がこの値だけ増やされて出力されます.

CALL HistoryAddVariable(...)

出力する変数を定義します. 各引数の意味は次のとおりです.

varname は変数の名前を指定します.
以下, gtool_history ではこの名前を用いて変数を参照あるいは指定したりすることになります.
dimsは変数の次元を次元名の配列で指定します.
dims=('x','t') では 2 次元配列であり, 1 次元目が 'x', 2 次元目が 't' であることを表しています.
longnameは長い方の名前です.
gtview 等の描画の際にタイトルとして用いられることになります.
unitsは変数の単位を表します.
無次元の場合には '1' を指定しましょう.
xtypeは変数の型を表します.
指定可能な型についてはレファレンスドキュメントを参照してください. xtype='double' は倍精度変数であることを表しています.

CALL HistoryPut('temp',temp)

定義した変数を出力します. 第一引数(varname)が出力する変数名です. あらかじめ HistoryAddVariable で定義されているか, HistoryCreate により次元変数として定義されている必要があります. 第二引数(array)が出力する値が格納されている配列です.

CALL HistoryClose

終了処理を行います. プログラムの最後にいれましょう.

次のステップ--属性(attribute)をつける

gtool4 では変数に属性をつけて情報を記録することができます. 記録するには

   
     call HistoryAddAttr(varname, attrname, value)

を呼ぶだけでできます. 第 1 引数が, 属性をつける変数名, 第 2 引数が属性名, 第 3 引数が属性の値です. 属性の型と次元は任意です. 文字型, 整数, 実数, 倍精度あるいはそれらの配列でも属性として記録することができます. 内部で自動的に判定されて出力されます.

例えば温度の等値線間隔のデフォルト値を与えるには

   
     call HistoryAddAttr('temp','gt_graph_contour_spacing',(/0.0,1.0,0.01/))

とすれば良いです. 出力ファイル全体に対する属性 (NetCDF でいうところの大域属性, global attribute)を指定するには, 属性名の先頭に'+' をつけて, 適当な変数に対して出力することになります.

   
     call HistoryAddAttr('temp','+gt_user_davis_kappa',kappa)

属性をつける変数として 'temp' としているにもかかわらず属性名に '+' がついてますので, ファイルには大域属性として出力されることになります.

そのような処理を施したプログラム例をこちらに示します.

さらなるステップ--複数ファイルに出力

ここで示した例では 1 つのファイルに全て値と属性の出力を行いました. しかしながら複数のファイルへ出力することもできます. こちらのサンプルプログラムを参照してみてください.

Fortran77 から使うには

上で示した例は Fortran90 で書かれたものです. しかしながら Fortran77 で書かれたプログラムに対してはこれまで示したようなやり方では gtool_history モジュールを使うことができません.

このために, Fortran77 用のインターフェースが別途用意してあります. Fortan90 用のインターフェースと比較して次のような制限があります.

複数のヒストリーファイルが使えない.
変数・属性の型・次元が自動判定されない. 型と次元に応じたサブルーチンを選択したり, 次元数や大きさを引数で与えなければならない.

使う際には, 対応する Fortran90 サブルーチンとは引数が異なっていることに注意してください. こちらのサンプルプログラムを参考にしてください. 各サブルーチンの詳しいドキュメントはこちらを参照してください.

gtool_history サンプルプログラムへ.
gtool4 ドキュメントへ.
gtool4 Top pageへ.

地球流体電脳倶楽部 davis プロジェクト

davis-ml(at)gfd-dennou.org

2001/02/28 更新 (by 竹広真一)