gtvargetattr.f90

Go to the documentation of this file.

!
!= 数値型属性の入力
!
! Authors::   Eizi TOYODA, Yasuhiro MORIKAWA
! Version::   $Id: gtvargetattr.f90,v 1.6 2010-06-17 00:41:41 morikawa Exp $
! Tag Name::  $Name:  $
! Copyright:: Copyright (C) GFD Dennou Club, 2000-2005. All rights reserved.
! License::   See COPYRIGHT[link:../../COPYRIGHT]
!
! 以下のサブルーチン, 関数は gtdata_generic から提供されます。
!
!--
! 引数の型に応じていろいろあるが、どうせ下部構造では同じモノを使っている。
!
! スカラで受け取るのが一番簡単。解釈可能な値がとられ、残りは捨てられる。
!++
 
subroutine gtvargetattri(var, attrname, value, default)
  !
  !== 属性の入力
  !
  ! 変数 *var* に付加されている属性 *name* の値を返します。
  ! *Get_Attr* は複数のサブルーチンの総称名なので、
  ! *value* には様々な型の変数 (ポインタも可能)
  ! を与えることが可能です。
  ! 以下のサブルーチンを参照してください。
  !
  ! 属性の値が正常に取得できず、且つ *default* が与えられて
  ! いた場合、その値が返ります。
  ! *default* が与えられない場合のデフォルトの値はそれぞれ以下の
  ! 通りです。
  !
  ! character :: "" (空文字)
  ! real      :: netcdf_f77#NF90_FILL_REAL
  ! real(DP)  :: netcdf_f77#NF90_FILL_DOUBLE
  ! integer   :: netcdf_f77#NF90_FILL_INT
  !
  ! *value* がポインタの場合は、型に依らず空状態が返ります。
  !
  ! *value* にポインタを与えた場合、属性の値に応じて自動的に
  ! 割り付けが行われます。そのため、必ず空状態にしてから与えてください。
  !
  ! *value* に固定長配列を用意する場合 *default* が必須になりますが、
  ! これは Fortran の言語仕様上ポインタ方式と引用仕様が同じであっては
  ! ならないからです。
  !
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use netcdf, only: nf90_fill_int
  use dc_string, only: stoi
  use dc_error, only: gt_enotvar, storeerror
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: attrname
  integer, intent(out):: value
  integer, intent(in), optional:: default
  integer:: stat, buffer(1), class, cid
  character(STRING):: cbuffer
  logical:: err
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call get_attr(gd_nc_variable(cid), attrname, buffer, stat, default)
    if (stat >= 1) then
      value = buffer(1)
      return
    end if
  else
    call storeerror(gt_enotvar, "GTVarGetAttrI")
  endif
  value = nf90_fill_int
  if (present(default)) value = default
end subroutine gtvargetattri
 
subroutine gtvargetattrr(var, attrname, value, default)
  use gtdata_types, only: gt_variable
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use dc_error, only: gt_ebadvar, storeerror
  use dc_string, only: stod
  use netcdf, only: nf90_fill_float
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: attrname
  real, intent(out):: value
  real, intent(in), optional:: default
  integer:: stat
  real:: buffer(1)
  character(STRING):: cbuffer
  integer:: class, cid
  logical:: err
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call get_attr(gd_nc_variable(cid), attrname, value=buffer, &
      & stat=stat, default=default)
    if (stat >= 1) then
      value = buffer(1)
      return
    endif
  else
    call storeerror(gt_ebadvar, "GTVarGetAttrR")
  endif
  if (present(default)) then
    value = default
  else
    value = nf90_fill_float
  endif
end subroutine gtvargetattrr
 
subroutine gtvargetattrd(var, attrname, value, default)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_string, only: stod
  use dc_error, only: gt_enotvar, storeerror
  use dc_types, only: dp
  use netcdf, only: nf90_fill_double
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: attrname
  real(DP), intent(out):: value
  real(DP), intent(in), optional:: default
  integer:: stat
  real(DP):: buffer(1)
  character(STRING):: cbuffer
  integer:: class, cid
  logical:: err
continue
  call var_class(var, class, cid)
  select case(class)
  case (vtb_class_netcdf)
    call get_attr(gd_nc_variable(cid), attrname, value=buffer, &
      & stat=stat, default=default)
    if (stat >= 1) then
      value = buffer(1)
      return
    end if
  case default
    call storeerror(gt_enotvar, "GTVarGetAttrR")
  end select
  value = nf90_fill_double
  if (present(default)) value = default
end subroutine
 
!
! ポインタ配列を使って受け取る場合は解釈可能な数だけ実体が割り付けられる。
!
 
subroutine gtvargetattrip(var, name, value)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_error, only: gt_enotvar, storeerror
  use dc_string, only: get_array
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: name
  integer, pointer:: value(:) !(out)
  integer:: stat, class, cid
  character(STRING):: cbuffer
  logical:: err
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    allocate(value(1))
    call get_attr(gd_nc_variable(cid), name, value(1:0), stat)
    deallocate(value)
    if (stat < 1) return
    allocate(value(stat))
    call get_attr(gd_nc_variable(cid), name, value, stat)
    if (stat < 1) deallocate(value)
  else
    call storeerror(gt_enotvar, "GTVarGetAttrIP")
  endif
end subroutine gtvargetattrip
 
subroutine gtvargetattrrp(var, name, value)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_string, only: get_array
  use dc_error, only: gt_enotvar, storeerror
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: name
  real, pointer:: value(:) !(out)
  integer:: stat, class, cid
  character(STRING):: cbuffer
  logical:: err
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    allocate(value(1))
    call get_attr(gd_nc_variable(cid), name, value(1:0), stat)
    deallocate(value)
    if (stat < 1) return
    allocate(value(stat))
    call get_attr(gd_nc_variable(cid), name, value, stat)
    if (stat < 1) deallocate(value)
  else
    nullify(value)
    call storeerror(gt_enotvar, "GTVarGetAttrRP")
  endif
end subroutine gtvargetattrrp
 
subroutine gtvargetattrdp(var, name, value)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_types, only: dp
  use dc_error, only: gt_enotvar, storeerror
  use dc_string, only: get_array
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: name
  real(DP), pointer:: value(:) !(out)
  integer:: stat, class, cid
  character(STRING):: cbuffer
  logical:: err
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    allocate(value(1))
    call get_attr(gd_nc_variable(cid), name, value(1:0), stat)
    deallocate(value)
    if (stat < 1) return
    allocate(value(stat))
    call get_attr(gd_nc_variable(cid), name, value, stat)
    if (stat < 1) deallocate(value)
  else
    call storeerror(gt_enotvar, "GTVarGetAttrRP")
  endif
end subroutine gtvargetattrdp
 
! integer 配列, real 配列として受け取る
! 場合は属性長があまっている場合には切り捨てられ、
! 属性長が足りない場合は default 値 (ポインタと違い必須) を埋める。
 
subroutine gtvargetattria(var, name, value, default)
  use gtdata_types, only: gt_variable
  use gtdata_generic, only: friend => get_attr
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_error, only: gt_enotvar, storeerror
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: name
  integer, intent(out):: value(:)
  integer, intent(in):: default
  integer, pointer:: ptr(:)
  integer:: n, stat, class, cid
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call get_attr(gd_nc_variable(cid), name, value, stat, default)
  else
    call storeerror(gt_enotvar, "GTVarGetAttrIA")
  endif
end subroutine gtvargetattria
 
subroutine gtvargetattrra(var, name, value, default)
  use gtdata_types, only: gt_variable
  use gtdata_generic, only: friend => get_attr
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_error, only: gt_enotvar, storeerror
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: name
  real, intent(out):: value(:)
  real, intent(in):: default
  real, pointer:: ptr(:)
  integer:: n, class, cid, stat
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call get_attr(gd_nc_variable(cid), name, value, stat, default)
  else
    call storeerror(gt_enotvar, "GTVarGetAttrRA")
  endif
end subroutine gtvargetattrra
 
subroutine gtvargetattrda(var, name, value, default)
  use gtdata_types, only: gt_variable
  use gtdata_generic, only: friend => get_attr
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_types, only: dp
  use dc_error, only: gt_enotvar, storeerror
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: name
  real(DP), intent(out):: value(:)
  real(DP), intent(in):: default
  real(DP), pointer:: ptr(:)
  integer:: n, stat, class, cid
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call get_attr(gd_nc_variable(cid), name, value, stat, default)
  else
    call storeerror(gt_enotvar, "GTVarGetAttrRA")
  endif
end subroutine gtvargetattrda