dcdatetimemul.f90

Go to the documentation of this file.

!= 利用者定義演算子 (*) のための関数
!= Functions for user defined operation (*)
!
! Authors::   Yasuhiro MORIKAWA, Eizi TOYODA
! Version::   $Id: dcdatetimemul.f90,v 1.2 2009-05-31 11:46:03 morikawa Exp $
! Tag Name::  $Name:  $
! Copyright:: Copyright (C) GFD Dennou Club, 2000-2005. All rights reserved.
! License::   See COPYRIGHT[link:../../COPYRIGHT]
!
  function dcdatetime_mul_if(factor, diff) result(result)
    !
    ! 日時差 *diff* と *facter* とを乗算した結果を返します.
    !
    use dc_date_types, only: dc_datetime, dc_difftime
    use dc_date_internal, only: dcdate_normalize
    use dc_scaledsec, only: operator(*)
    implicit none
    type(dc_difftime):: result
    integer, intent(in):: factor
    type(dc_difftime), intent(in):: diff
  continue
    result % mon = factor * diff % mon
    result % day = factor * diff % day
    result % sec = factor * diff % sec
    result % day_seconds = diff % day_seconds
    result % nondim_flag = diff % nondim_flag
    call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
  end function dcdatetime_mul_if
 
  function dcdatetime_mul_fi(diff, factor) result(result)
    use dc_date_generic, only: operator(*)
    use dc_date_types, only: dc_datetime, dc_difftime
    implicit none
    type(dc_difftime):: result
    type(dc_difftime), intent(in):: diff
    integer, intent(in):: factor
  continue
    result = factor * diff
  end function dcdatetime_mul_fi
 
  function dcdatetime_mul_rf(factor, diff) result(result)
    !
    ! ※ 注意 : 月差を非整数倍すると近似的結果になるおそれがあります
    use dc_date_generic, only: operator(*)
    use dc_date_types, only: dc_datetime, dc_difftime
    use dc_types, only: dp
    implicit none
    type(dc_difftime):: result
    real, intent(in):: factor
    type(dc_difftime), intent(in):: diff
  continue
    result = real(factor, dp) * diff
  end function dcdatetime_mul_rf
 
  function dcdatetime_mul_fr(diff, factor) result(result)
    !
    ! ※ 注意 : 月差を非整数倍すると近似的結果になるおそれがあります
    use dc_date_generic, only: operator(*)
    use dc_date_types, only: dc_datetime, dc_difftime
    implicit none
    type(dc_difftime):: result
    type(dc_difftime), intent(in):: diff
    real, intent(in):: factor
  continue
    result = factor * diff
  end function dcdatetime_mul_fr
 
  function dcdatetime_mul_df(factor, diff) result(result)
    !
    ! ※ 注意 : 月差を非整数倍すると近似的結果になるおそれがあります
    use dc_date_internal, only: dcdate_normalize
    use dc_date_types, only: cyclic_mdays, dc_datetime, dc_difftime
    use dc_scaledsec, only: dc_scaled_sec, &
      & operator(<), operator(>), operator(<=), operator(>=), &
      & operator(+), operator(-), operator(*), operator(/), &
      & modulo, int, abs, sign
    use dc_types, only: dp
    implicit none
    type(dc_difftime):: result
    real(dp), intent(in):: factor
    type(dc_difftime), intent(in):: diff
    type(dc_scaled_sec):: month, day
  continue
    month = factor * diff % mon
    result % mon = int(month)
    day = factor * diff % day + int(cyclic_mdays * (month - result % mon))
    result % day = int(day)
    result % sec = &
      & factor * diff % sec + (day - result % day) * diff % day_seconds
    result % day_seconds = diff % day_seconds
    result % nondim_flag = diff % nondim_flag
    call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
  end function dcdatetime_mul_df
 
  function dcdatetime_mul_fd(diff, factor) result(result)
    !
    ! ※ 注意 : 月差を非整数倍すると近似的結果になるおそれがあります
    use dc_date_generic, only: operator(*)
    use dc_date_types, only: dc_datetime, dc_difftime
    use dc_types, only: dp
    implicit none
    type(dc_difftime):: result
    type(dc_difftime), intent(in):: diff
    real(dp), intent(in):: factor
  continue
    result = factor * diff
  end function dcdatetime_mul_fd